여러분은 고등학교에서 매개변수를 사용하여 함수를 표시하는 방법을 공부하였을 것입니다.

예를 들면 원은 x=cos t, y=sin t 로 나타낼 수 있읍니다. 이러한 함수의 그래프는 다음과 같이 그릴 수 있읍니다.

> plot([cos(t),sin(t),t=0..2*Pi]);
> plot([t-sin(t),1-cos(t),t=0..4*Pi]);
> plot([3*cos(t)+cos(3*t),3*sin(t)-sin(3*t),t=0..2*Pi]);
> plot3d([cos(s)*(3+cos(t)),sin(s)*(3+cos(t)),sin(t)],s=0..2*Pi,t=0..2*Pi);

극좌표를 이용하여 그래프 r=r(theta) 를 그릴 때에는 polarplot 함수를 이용합니다.

이 함수는 plots 패키지에 포함되어 있으므로 with(plots):를 입력해야 합니다.

> with(plots):
> polarplot(1+2*sin(theta),theta=0..2*Pi);
> polarplot(theta/4,theta=0..8*Pi);
> polarplot(sin(4*theta),theta=0..2*Pi,axes=none,color=blue);

극좌표에서의 매개방정식 r=f(t) , theta=g(t) 를 그릴 때에도 마찬가지로 합니다.

> polarplot([sin(t),cos(t),t=0..2*Pi]);

좌표가 주어진 점들을 그래프로 나타낼 때에도 plot를 쓸 수 있읍니다.

display는 그려진 plot을 보여주는 함수인데, 여러 개의 plot을 동시에 보여주기 위해서 사용합니다.

display를 사용하기 위해서는 with(plots):를 입력하여 plots 패키지를 불러야 합니다.

> data_list:=[[-2,4],[-1,1],[0,0],[1,1],[2,4],[3,9],[4,16]];
> plot(data_list);
> plot(data_list,style=point,symbol=box);
> a := plot(data_list,color=blue):
> b := plot(data_list,style=point,symbol=box):
> with(plots):
> display(a,b);

그래프에 여러 가지 방법으로 주석을 달 수 있읍니다. 여기에서 주의할 것은 Maple에서는 string을 back quote(‘)를 이용해서 나타낸다는 것입니다.

> plot(sin(x),x=-Pi..Pi,title=`Graph of sin(x)`);

원하는 위치에 주석을 달기 위해서는 textplot을 이용해야 합니다.

이 함수를 사용하기 위해서는 with(plots):를 입력하여 plots 패키지를 불러야 합니다.

> with(plots):
> a:=plot(sin(x),x=-Pi..Pi):
> b:=textplot([Pi/2,1,`Local Maximum`]):
> c:=textplot([-Pi/2,-1,`Local Minimum`]):
> display(a,b,c);